| 1 | # confclerk.pro |
|---|
| 2 | |
|---|
| 3 | QMAKEVERSION = $$[QMAKE_VERSION] |
|---|
| 4 | ISQT4 = $$find(QMAKEVERSION, ^[2-9]) |
|---|
| 5 | isEmpty( ISQT4 ) { |
|---|
| 6 | error("Use the qmake include with Qt4.4 or greater, on Debian that is qmake-qt4"); |
|---|
| 7 | } |
|---|
| 8 | |
|---|
| 9 | TEMPLATE = subdirs |
|---|
| 10 | SUBDIRS = src |
|---|
| 11 | |
|---|
| 12 | # The global.pri defines the VERSION of the project |
|---|
| 13 | include(src/global.pri) |
|---|
| 14 | |
|---|
| 15 | |
|---|
| 16 | QMAKE_DISTCLEAN += data/$${TARGET}.png data/$${TARGET}.1 ChangeLog |
|---|
| 17 | QMAKE_EXTRA_TARGETS += changelog icon man release tarball |
|---|
| 18 | |
|---|
| 19 | changelog.target = ChangeLog |
|---|
| 20 | changelog.commands = \ |
|---|
| 21 | svn up && svn2cl --group-by-day --reparagraph |
|---|
| 22 | changelog.CONFIG = phony |
|---|
| 23 | |
|---|
| 24 | icon.target = data/$${TARGET}.png |
|---|
| 25 | icon.commands = convert data/$${TARGET}.svg data/$${TARGET}.png |
|---|
| 26 | icon.depends = data/$${TARGET}.svg |
|---|
| 27 | |
|---|
| 28 | man.target = data/$${TARGET}.1 |
|---|
| 29 | man.commands = pod2man --utf8 --center=\"Offlince conference scheduler\" --release=\"Version $${VERSION}\" data/$${TARGET}.pod > data/$${TARGET}.1 |
|---|
| 30 | man.depends = data/$${TARGET}.pod |
|---|
| 31 | |
|---|
| 32 | release.depends = tarball |
|---|
| 33 | |
|---|
| 34 | tarball.target = $${TARGET}-$${VERSION}.tar.gz |
|---|
| 35 | tarball.commands = \ |
|---|
| 36 | $(DEL_FILE) -r $${TARGET}-$${VERSION} ; \ |
|---|
| 37 | $(MKDIR) $${TARGET}-$${VERSION} ; \ |
|---|
| 38 | $(COPY_DIR) * $${TARGET}-$${VERSION}/ ; \ |
|---|
| 39 | $(DEL_FILE) $${TARGET}-$${VERSION}/*.pro.user \ |
|---|
| 40 | $${TARGET}-$${VERSION}/$${TARGET}-$${VERSION}.tar.gz \ |
|---|
| 41 | $(DEL_FILE) -r $${TARGET}-$${VERSION}/$${TARGET}-$${VERSION} \ |
|---|
| 42 | $${TARGET}-$${VERSION}/Makefile ; \ |
|---|
| 43 | tar -cz --exclude=.svn -f $$tarball.target $${TARGET}-$${VERSION} ; \ |
|---|
| 44 | $(DEL_FILE) -r $${TARGET}-$${VERSION} |
|---|
| 45 | tarball.depends = changelog icon man |
|---|
