source: confclerk_git/confclerk.pro @ 664e8bd

qt5
Last change on this file since 664e8bd was 664e8bd, checked in by gregor herrmann <gregoa@…>, 11 years ago

Don't remove generated files in DISTCLEAN; otherwise they are gone during package builds :/

  • Property mode set to 100644
File size: 1.4 KB
Line 
1# confclerk.pro
2
3QMAKEVERSION = $$[QMAKE_VERSION]
4ISQT4 = $$find(QMAKEVERSION, ^[2-9])
5isEmpty( ISQT4 ) {
6        error("Use the qmake include with Qt4.4 or greater, on Debian that is qmake-qt4");
7}
8
9TEMPLATE = subdirs
10SUBDIRS = src
11
12# The global.pri defines the VERSION of the project
13include(src/global.pri)
14
15
16QMAKE_EXTRA_TARGETS += changelog icon man release tarball
17
18changelog.target = ChangeLog
19changelog.commands = \
20        svn up && svn2cl --group-by-day --reparagraph
21changelog.CONFIG = phony
22
23icon.target = data/$${TARGET}.png
24icon.commands = convert data/$${TARGET}.svg data/$${TARGET}.png
25icon.depends = data/$${TARGET}.svg
26
27man.target = data/$${TARGET}.1
28man.commands = pod2man --utf8 --center=\"Offlince conference scheduler\" --release=\"Version $${VERSION}\" data/$${TARGET}.pod > data/$${TARGET}.1
29man.depends = data/$${TARGET}.pod
30
31release.depends = tarball
32
33tarball.target = $${TARGET}-$${VERSION}.tar.gz
34tarball.commands = \
35        $(DEL_FILE) -r $${TARGET}-$${VERSION} ; \
36        $(MKDIR) $${TARGET}-$${VERSION} ; \
37        $(COPY_DIR) * $${TARGET}-$${VERSION}/ ; \
38        $(DEL_FILE) $${TARGET}-$${VERSION}/*.pro.user \
39                $${TARGET}-$${VERSION}/$${TARGET}-$${VERSION}.tar.gz \
40                $(DEL_FILE) -r $${TARGET}-$${VERSION}/$${TARGET}-$${VERSION} \
41                $${TARGET}-$${VERSION}/Makefile ; \
42        tar -cz --exclude=.svn -f $$tarball.target $${TARGET}-$${VERSION} ; \
43        $(DEL_FILE) -r $${TARGET}-$${VERSION}
44tarball.depends = changelog icon man
Note: See TracBrowser for help on using the repository browser.