source: src/app/app.pro @ 22232d9

qt5
Last change on this file since 22232d9 was 22232d9, checked in by kirilma <kirilma@…>, 12 years ago

build fix at maemo

force order of computation
some versions of qmake-qt4 require it

  • Property mode set to 100644
File size: 1.1 KB
Line 
1include(../global.pri)
2TEMPLATE = app
3TARGET = fosdem-schedule
4DESTDIR = ../bin
5QT += sql xml network dbus
6
7# module dependencies
8LIBS += -L$$DESTDIR -lgui -lmvc -lsql
9INCLUDEPATH += ../gui ../sql ../mvc ../orm
10DEPENDPATH += . ../gui
11TARGETDEPS += $$DESTDIR/libmvc.a $$DESTDIR/libgui.a $$DESTDIR/libsql.a
12maemo {
13    LIBS += -L$$DESTDIR -lqalarm -lalarm
14    INCLUDEPATH += ../alarm
15    DEPENDPATH +=  ../alarm
16    TARGETDEPS += $$DESTDIR/libqalarm.a
17}
18
19HEADERS += appsettings.h \
20        application.h \
21    alarmdbus.h \
22        alarmdbusadaptorp.h
23
24SOURCES += main.cpp \
25           application.cpp \
26           appsettings.cpp \
27    alarmdbus.cpp \
28        alarmdbusadaptor.cpp
29
30RESOURCES += ../icons.qrc \
31             ../maps.qrc
32
33# qmake cannot work properly if the resource file does not exist already
34system(rm -f ../fosdem.sqlite && sqlite3 ../fosdem.sqlite <../fosdem.sql) {
35 RESOURCES += ../db.qrc
36} else {
37 error(sqlite3 failed)
38}
39
40db.target = ../fosdem.sqlite
41db.depends = ../fosdem.sql
42db.commands = rm -f $$db.target && sqlite3 $$db.target <$$db.depends
43QMAKE_EXTRA_TARGETS += db
44
45# instalation related
46
47PREFIX = /usr/bin
48INSTALLS = target
49target.path = $$PREFIX
50
Note: See TracBrowser for help on using the repository browser.